Hướng dẫn Rebuild 1Click - LK để tạo Menuboot cho USB HDD

bangthong · 21/11/13

khatmau: chỉ dùm làm sao để đổi được ảnh nền?

quan174 · 28/12/13

sao em ko minh ko thay code run.bat dau ca

quan174 · 29/12/13

cách thay lại hình tiểu long nữ như thế nào vay anh?

nhatdaochem · 29/12/13

quan174 nói:

Bạn lên google tìm file Gfxmenu rùi theo hướng dẫn là có thể làm đc

)

milan88 · 9/2/14

Từ : "Lãng Khách" trong bài nhiều quá

hiepsisoma · 9/2/14

milan88 nói:

Anh LK thích cá nhân hóa mà, với lại đây là công cụ tự làm nên cũng dễ hiểu :look_down:

milan88 · 9/2/14

hiepsisoma nói:

Dễ mà Nhưng mình không khó

quan174 · 21/4/14

răng mình giải nén 1click ra thì chỉ thấy 1 file duy nhất là :runme.bat;
ko thấy file nào khác

hiepsisoma · 21/4/14

quan174 nói:

Show file ẩn mới thấy

quan174 · 21/4/14

làm hiện file ẩn ở chổ nào vậy anh. em dùng win xp

hiepsisoma · 21/4/14

quan174 nói:

Bạn hỏi thằng Google

giatruat · 26/9/14

tks. bài này rất hay. cái này chỉ cách làm 1click k phải chỉ cách làm menu boot mà :P

lll_C7G_lll · 9/12/14

mr.trung91 nói:

Và đây là code mình rebuild lại

Mã:

@echo off
color 0a
title Tao Menu boot USB/HDD 1 Click
set tit1=           ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
set tit2=                =========== Mr.Trung91@yahoo.com.vn ===========
:Ktsys
if %systemdrive%\==X:\ (
goto Not
)
:Ktfile
for %%x in (BOOTICE.exe grldr.mbr grldr menu.lst Ghost.iso) do if not exist  files\%%x (
goto Thieufile
)
:Kt7
if not exist "%PUBLIC%" (
goto KtXP
)
for /f "Tokens=*" %%a in ('net localgroup Administrators^|find /i "%username%"') do goto Start
cls
echo.
echo %tit1%
echo %tit2%
echo.
echo.
echo Ban dang khong chay voi quyen Administrator!
echo.
echo Hay phai chuot file nay va chon Run as Administrator!
echo.
@pause
goto End
:KtXP
for /f "Tokens=*" %%a in ('net localgroup Administrators^|find /i "%username%"') do goto Start
cls
echo.
echo %tit1%
echo %tit2%
echo.
echo.
echo Ban dang khong chay voi quyen Admin!
echo.
echo Hay chay lai file nay voi user thuoc nhom Admin!
echo.
@pause
goto End
:Thieufile
cls
echo.
echo %tit1%
echo %tit2%
echo.
echo.
echo Thieu file (BOOTICE.exe grldr.mbr grldr menu.lst Ghost.iso)...
echo.
echo Tien trinh khong the tiep tuc.
echo.
@pause
goto End
:Loicopy
cls
echo.
echo %tit1%
echo %tit2%
echo.
echo.
echo Co loi trong qua trinh Copy file...
echo.
echo Ban hay kiem tra can than va thuc hien lai nhe.
echo.
@pause
goto End
:Start
cls
echo.
echo %tit1%
echo %tit2%
echo.
echo.
set Setup=
set /P Setup=Nhap 1 de cai vao HDD, nhap 2 de cai vao USB:
echo.
IF %Setup%==2 goto USB
IF %Setup%==1 goto HDD
goto Start
:HDD
:Win7
if not exist "%PUBLIC%" (
goto WinXP
)
if exist "%systemdrive%\BCD.OK" (
goto Go7
)
:Cai7
cls
echo.
echo %tit1%
echo %tit2%
echo.
echo.
echo Menu "Start Grub4Dos" se duoc cai vao phan vung he thong %systemdrive%\
echo.
echo Neu ban chac chan, bam phim bat ki de tiep tuc.
echo.
echo Hoac tat cua so nay de huy bo.
echo.
@pause
echo BCDEDIT /export %systemdrive%\BCD.OK&&BCDEDIT /export %systemdrive%\BCD.OK
for /f "tokens=3" %%a in ('bcdedit /create /d "Start Grub4Dos" /application BOOTSECTOR') do set guid=%%a
echo bcdedit /set %guid% device boot&&bcdedit /set %guid% device boot
echo bcdedit /set %guid% device partition=%systemdrive%&&bcdedit /set %guid% device partition=%systemdrive%
echo bcdedit /set %guid% PATH \grldr.mbr&&bcdedit /set %guid% PATH \grldr.mbr
echo bcdedit /displayorder %guid% /addlast&&bcdedit /displayorder %guid% /addlast
echo bcdedit /timeout 5&&bcdedit /timeout 5
for %%x in (grldr.mbr grldr menu.lst Ghost.iso) do attrib -r -h -s %systemdrive%\%%x >nul 2>nul
for %%x in (grldr.mbr grldr menu.lst Ghost.iso) do echo copy /y files\%%x %systemdrive%\ &&copy /y files\%%x %systemdrive%\
for %%x in (grldr.mbr grldr menu.lst Ghost.iso BCD.OK) do if not exist  %systemdrive%\%%x goto Loicopy
for %%x in (grldr.mbr grldr menu.lst Ghost.iso BCD.OK) do attrib +r +h +s %systemdrive%\%%x >nul 2>nul
cls
echo.
echo %tit1%
echo %tit2%
echo.
echo.
echo Da copy xong cac file can thiet va hoan tat Menu boot.
echo.
@pause
goto End
:Go7
cls
echo.
echo %tit1%
echo %tit2%
echo.
echo.
set ChoiceW7=
set /P ChoiceW7=Menu boot da co san. Ban co muon go bo khong? (Y/N):
echo.
IF /I NOT '%ChoiceW7%'=='Y' IF /I NOT '%ChoiceW7%'=='N' goto Go7
IF /I '%ChoiceW7%'=='Y' (
attrib -r -h -s "%systemdrive%\BCD.OK"
BCDEDIT /import "%systemdrive%\BCD.OK"
for %%x in (grldr.mbr grldr menu.lst Ghost.iso) do echo del /a /f /q %systemdrive%\%%x&&del /a /f /q %systemdrive%\%%x
echo del /a /f /q %systemdrive%\BCD.OK*&&del /a /f /q %systemdrive%\BCD.OK*
cls
echo.
echo %tit1%
echo %tit2%
echo.
echo.
echo Da go bo xong Menu boot.
echo.
echo Ban nho RESTART may tinh truoc khi cai lai Menu boot...
echo.
@pause
goto End
)
goto Cai7
:WinXP
if exist "%systemdrive%\boot.ok" (
goto GoXP
)
:CaiXP
cls
echo.
echo %tit1%
echo %tit2%
echo.
echo.
echo Menu "Start Grub4Dos" se duoc cai vao phan vung %systemdrive%\
echo.
echo Neu ban chac chan, bam phim bat ki de tiep tuc.
echo.
echo Hoac tat cua so nay de huy bo.
echo.
@pause
attrib -R -H -S "%systemdrive%\boot.ini" >nul 2>nul
attrib -R -H -S "%systemdrive%\boot.ok" >nul 2>nul
echo copy /y "%systemdrive%\boot.ini" "%systemdrive%\boot.ok"&&copy /y "%systemdrive%\boot.ini" "%systemdrive%\boot.ok"
>>"%systemdrive%\boot.ini" echo.
>>"%systemdrive%\boot.ini" echo %systemdrive%\grldr.mbr="Start Grub4Dos"
echo bootcfg /timeout 5&&bootcfg /timeout 5
attrib +R +H +S "%systemdrive%\boot.ini" >nul 2>nul
for %%x in (grldr.mbr grldr menu.lst Ghost.iso) do attrib -r -h -s %systemdrive%\%%x >nul 2>nul
for %%x in (grldr.mbr grldr menu.lst Ghost.iso) do echo copy /y files\%%x %systemdrive%\ &&copy /y files\%%x %systemdrive%\
for %%x in (grldr.mbr grldr menu.lst Ghost.iso boot.ok) do if not exist  %systemdrive%\%%x goto Loicopy
for %%x in (grldr.mbr grldr menu.lst Ghost.iso boot.ok) do attrib +r +h +s %systemdrive%\%%x >nul 2>nul
cls
echo.
echo %tit1%
echo %tit2%
echo.
echo.
echo Da copy xong cac file can thiet va hoan tat menu boot.
echo.
@pause
goto End
:GoXP
cls
echo.
echo %tit1%
echo %tit2%
echo.
echo.
set ChoiceXP=
set /P ChoiceXP=Menu boot da co san. Ban co muon go bo khong? (Y/N):
IF /I NOT '%ChoiceXP%'=='Y' IF /I NOT '%ChoiceXP%'=='N' goto GoXP
IF /I '%ChoiceXP%'=='Y' (
echo del /a/f/q "%systemdrive%\boot.ini"&&del /a/f/q "%systemdrive%\boot.ini"
attrib -R -H -S "%systemdrive%\boot.ok" >nul 2>nul
echo copy /y "%systemdrive%\boot.ok" "%systemdrive%\boot.ini"&&copy /y "%systemdrive%\boot.ok" "%systemdrive%\boot.ini"
attrib +R +H +S "%systemdrive%\boot.ini"
for %%x in (grldr.mbr grldr menu.lst Ghost.iso boot.ok) do echo del /a /f /q %systemdrive%\%%x&&del /a /f /q %systemdrive%\%%x
cls
echo.
echo %tit1%
echo %tit2%
echo.
echo.
echo Da go bo xong Menu boot.
echo.
@pause
goto End
)
goto CaiXP
:USB
:Ktusb
for /f "Tokens=*" %%x in ('WMIC LOGICALDISK GET DESCRIPTION^|FIND /i "Removable"') do goto Ustart
cls
echo.
echo %tit1%
echo %tit2%
echo.
echo.
echo Khong tim thay USB tren he thong. Ban hay gan USB vao may!
echo.
echo Roi bam phim bat ky de tiep tuc...
echo.
@pause
goto Ktusb
:Ustart
cls
echo.
echo %tit1%
echo %tit2%
echo.
echo.
echo Day la danh sach cac o USB dang co tren may ban:
echo.
echo (Dang luu tru) (O USB)   (Nhan USB)
echo.
wmic logicaldisk get DESCRIPTION,DEVICEID,VOLUMENAME|FINDSTR "Removable"
echo.
echo Ban hay nhap 'O USB' can tao boot voi '01 CHU CAI'
echo.
set /p drive=(Vi du: D,E,F,G,H,I,J,K,...) roi nhan Enter:
del /f /q /a  %tmp%\test.txt >nul 2>nul
wmic logicaldisk get DESCRIPTION,DEVICEID,VOLUMENAME|FINDSTR "Removable" > %tmp%\test.txt
IF /I '%drive%'=='' goto Ktusb
find /c /i "%drive%:" "%tmp%\test.txt" > NUL 2>NUL
if %ERRORLEVEL% == 0 (
del /f /q /a  %tmp%\test.txt >nul 2>nul
goto Testusb
)
cls
echo.
echo %tit1%
echo %tit2%
echo.
echo.
echo Ten USB ban nhap khong dung. Bam phim bat ki de nhap lai.
echo.
@pause
goto Ktusb
:Testusb
echo.
echo Dang kiem tra kha nang ghi xoa cua USB >%drive%:\test.ok
if not exist %drive%:\test.ok (
cls
echo.
echo %tit1%
echo %tit2%
echo.
echo.
echo O dia USB %drive%:\ Khong the ghi du lieu, Ban hay kiem tra lai.
echo.
echo Nhan phim bat ki de tiep tuc...
echo.
@pause
goto Ktusb
)
del /q /f /a %drive%:\test.ok>nul 2>nul
if exist %drive%:\test.ok (
cls
echo.
echo %tit1%
echo %tit2%
echo.
echo.
echo O dia USB %drive%:\ Khong the ghi du lieu, Ban hay kiem tra lai.
echo.
echo Nhan phim bat ki de tiep tuc...
echo.
@pause
goto Ktusb
)
:FormatUSB
cls
echo.
echo %tit1%
echo %tit2%
echo.
echo.
SET Format=
SET /P Format=Ban co muon Format lai O dia USB %drive%:\ khong (Y/N)?:
echo.
IF /I NOT '%Format%'=='Y' IF /I NOT '%Format%'=='N' goto FormatUSB
IF /I '%Format%'=='Y' (
goto Yes
)
goto No

:Yes
files\BOOTICE.exe /DEVICE=%drive%: /partitions /format_usb /usb-hdd /fstype=fat32 /auto

:No
files\BOOTICE.exe /DEVICE=%drive%: /mbr /install /type=Grub4dos /boot_file=grldr /mbr-disable-floppy /auto
files\BOOTICE.exe /DEVICE=%drive%: /pbr /install /type=Grub4dos /@ctivate /auto
for %%x in (grldr menu.lst Ghost.iso) do attrib -r -h -s %drive%:\%%x >nul 2>nul
for %%x in (grldr menu.lst Ghost.iso) do echo copy /y files\%%x %drive%:\&&copy /y files\%%x %drive%:\
for %%x in (grldr menu.lst Ghost.iso) do if not exist  %drive%:\%%x goto Loicopy
cls
echo.
echo %tit1%
echo %tit2%
echo.
echo.
Echo USB cua ban da duoc tao Boot. Va san sang de su dung.
echo.
@pause
goto End

:Not
cls
echo.
echo %tit1%
echo %tit2%
echo.
echo.
echo Khong the su dung tools nay trong MiniXP hoac Win7PE !
echo.
@pause

:End
rd /s /q files
del /f /q /a TM.bat

Nhìn code của bạn rất dễ hiểu

mathanhnam · 7/1/16

[Thông Báo] Tuyển thành viên viết bài KIẾM TIỀN trên PhienBanMoi.Com

Hướng dẫn Rebuild 1Click - LK để tạo Menuboot cho USB HDD

bangthong

Member Chính Thức

quan174

Member Chính Thức

quan174

Member Chính Thức

nhatdaochem

Member Chính Thức

milan88

Member Chính Thức

hiepsisoma

Yêu Thích Sự Phản Đối

milan88

Member Chính Thức

quan174

Member Chính Thức

hiepsisoma

Yêu Thích Sự Phản Đối

quan174

Member Chính Thức

hiepsisoma

Yêu Thích Sự Phản Đối

giatruat

Member Mới

lll_C7G_lll

♥→ Milker ←♥

mathanhnam

Member Chính Thức

Bài xem nhiều